se/SE/schema/default_db_xml_cache.public/ant.xsl

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:Types__x3A__ant="https://biuro.biall-net.pl/wfs/default_db/Types/ant.xsd"
    xmlns:Types__x3A__POPC="https://biuro.biall-net.pl/wfs/default_db/Types/POPC.xsd"
    xmlns:Types__x3A__wfs="https://biuro.biall-net.pl/wfs/default_db/Types/wfs.xsd"
    exclude-result-prefixes="xs"
    version="2.0">
    
    <xsl:param name="wget" select="'/opt/local/bin/wget'"/>
    <xsl:param name="csv2xml" select="'/opt/local/bin/csv2xml'"/>
    <xsl:param name="curl" select="'/opt/local/bin/curl'"/>
    <xsl:param name="Types__x3A__wfs:username" required="yes" />
    <xsl:param name="Types__x3A__wfs:username-pass" required="yes" />
    
    
    <xsl:output indent="yes"/>
    
    <!-- template do tworzenia szybkich zorganizowanych skryptow do budowy czegos np sciagania danych wget -->
    
    <xsl:template match="project[@basedir and @name and @poprawione_xml_dir]" mode="Types__x3A__ant:project" xpath-default-namespace="https://biuro.biall-net.pl/wfs/default_db/Types/ant.xsd">
        <xsl:param name="default" select="'DEFAULT'"/>
        <xsl:variable name="basedir" select="@basedir"/>
        <xsl:variable name="name"  select="@name"/>
         <!-- taski do przetworzenia w templates-->
        <project basedir="." name="{@name}"  default="{$default}" >
            <mkdir dir="{$basedir}" />
            <xsl:if test="@poprawione_xml_dir"><mkdir dir="{@poprawione_xml_dir}" /></xsl:if>
            <xsl:for-each select="@mkdir">
                <mkdir dir="{.}"/>
            </xsl:for-each>
            <xsl:apply-templates mode="Types__x3A__ant:tasks">
                <xsl:with-param name="basedir" select="$basedir"/>
                <xsl:with-param name="poprawione_xml_dir" select="@poprawione_xml_dir"/>
            </xsl:apply-templates>
            <xsl:variable name="dependency"><xsl:apply-templates mode="Types__x3A__ant:tasks_dependencies"/></xsl:variable>
            <!--<debug><xsl:copy-of select="$dependency"></xsl:copy-of></debug>-->
            <xsl:element name="target">
                <xsl:attribute name="name" select="$default"/>
                
                <xsl:attribute name="depends">
                    <xsl:for-each select="$dependency//text()">
                        <xsl:value-of select="."/>
                        <xsl:if test="position()!=last()">,</xsl:if>
                    </xsl:for-each>
                </xsl:attribute>
                    
                
                <echo message="Target complete"/>
            </xsl:element>
        </project>
    </xsl:template>
    
    <xsl:template match="project" mode="Types__x3A__ant:project" xpath-default-namespace="https://biuro.biall-net.pl/wfs/default_db/Types/ant.xsd">
        <xsl:message terminate="yes">ERROR not all requred attributes set! </xsl:message>
    </xsl:template>
    
    <xsl:template match="wget" mode="Types__x3A__ant:tasks" xpath-default-namespace="https://biuro.biall-net.pl/wfs/default_db/Types/ant.xsd">
        <xsl:param name="basedir" select="'.'"/>
        <target name="{@Target_file}_check">
            <echo message="Check for {@Target_file}"/>
            <condition property="{@Target_file}_install" value="AVIABLE" taskname="DEFAULT">
                <available  type="file" file="{@Target_file}" filepath="{$basedir}"/>
            </condition>
        </target>
        <target name="{@Target_file}_install" unless="{@Target_file}_install">
            <exec executable="{$wget}" dir="{$basedir}">
                <arg value="{@Target}"/>
                <arg value="-O"/>
                <arg value="{@Target_file}"/>
            </exec>
        </target>
    </xsl:template>
    
    <xsl:template match="curl_post_wfst" mode="Types__x3A__ant:tasks" xpath-default-namespace="https://biuro.biall-net.pl/wfs/default_db/Types/ant.xsd">
        <xsl:param name="basedir" select="'.'"/>
        <xsl:param name="poprawione_xml_dir"  required="yes"/>
        <target name="{@Target_file}_check">
            <echo message="Check for {@Target_file}"/>
            <condition property="{@Target_file}_install" value="AVIABLE" taskname="DEFAULT">
                <available  type="file" file="{@Target_file}" filepath="{$poprawione_xml_dir}"/>
            </condition>
        </target>
        <target name="{@Target_file}_install" unless="{@Target_file}_install">
            <exec executable="{$curl}" dir="{$basedir}"  failonerror="true">
                <arg value="-X"/>
                <arg value="POST"/>
                <arg value="--user"/>
                <arg><xsl:attribute name="value" select="concat($Types__x3A__wfs:username,':',$Types__x3A__wfs:username-pass)"/></arg>
                <arg value="-d"/>
                <arg value="@{@Target_file}"/>
                <arg value="{@Target}"/>
                <!--<arg value="-\-user {$Types__x3A__wfs:username}:{$Types__x3A__wfs:username-pass} "/>-->
                <arg value="-v"/>
                <arg value="--insecure"/>
                <!--<arg value="-O"/>
                <arg value="{@Target_file}"/>-->
            </exec>
            <touch file="{$poprawione_xml_dir}/{@Target_file}"/>
        </target>
    </xsl:template>
    
    
    <xsl:template match="csv2xml[@csvfile and @xmlfile ]" mode="Types__x3A__ant:tasks" xpath-default-namespace="https://biuro.biall-net.pl/wfs/default_db/Types/ant.xsd">
        <xsl:param name="basedir" select="'.'"/>
        <xsl:param name="poprawione_xml_dir"  required="yes"/>
        <target name="{@xmlfile}_csv2xml_check">
            <echo message="Check for {@xmlfile}"/>
            <condition property="{@xmlfile}_csv2xml_install" value="AVIABLE" taskname="DEFAULT">
                <available  type="file" file="{@xmlfile}" filepath="{$basedir}"/>
            </condition>
        </target>
        <target name="{@xmlfile}_csv2xml_install" unless="{@xmlfile}_csv2xml_install">
            <exec executable="{$csv2xml}" dir="{$basedir}" input="{$basedir}/{@csvfile}" output="{$basedir}/{@xmlfile}"/>         
            <echo message=" Poprawiam plik XML aby mial znanczik xml oraz element root"/>
            <concat destfile="{$poprawione_xml_dir}/{@xmlfile}" append="false" encoding="UTF-8" >
                <string>&lt;?xml version="1.0" encoding="UTF-8"?&gt;
                    &lt;root&gt;</string>
                <file file="{$basedir}/{@xmlfile}"/>
                <string>&lt;/root&gt;</string>
            </concat>
        </target>
    </xsl:template>
    
    <xsl:template match="csv2xml" mode="Types__x3A__ant:tasks" xpath-default-namespace="https://biuro.biall-net.pl/wfs/default_db/Types/ant.xsd">
        <xsl:message terminate="yes">Error not typed all [@csvfile and @xmlfile] attributes to <xsl:copy-of select="."/></xsl:message>
    </xsl:template>
    
    <xsl:template match="wget" mode="Types__x3A__ant:tasks_dependencies" xpath-default-namespace="https://biuro.biall-net.pl/wfs/default_db/Types/ant.xsd">
            <xsl:apply-templates select="@*" mode="Types__x3A__ant:tasks_wget_dependencies"/>
    </xsl:template>
    <xsl:template match="csv2xml" mode="Types__x3A__ant:tasks_dependencies" xpath-default-namespace="https://biuro.biall-net.pl/wfs/default_db/Types/ant.xsd">
        <xsl:apply-templates select="@*" mode="Types__x3A__ant:tasks_csv2xml_dependencies"/>
    </xsl:template>
    
    <xsl:template match="curl_post_wfst" mode="Types__x3A__ant:tasks_dependencies" xpath-default-namespace="https://biuro.biall-net.pl/wfs/default_db/Types/ant.xsd">
        <xsl:apply-templates select="@*" mode="Types__x3A__ant:tasks_curl_post_wfst_dependencies"/>
    </xsl:template>
    
    <xsl:template match="*" mode="Types__x3A__ant:tasks_dependencies  Types__x3A__ant:tasks_wget_dependencies  Types__x3A__ant:tasks_csv2xml_dependencies Types__x3A__ant:tasks_curl_post_wfst_dependencies" xpath-default-namespace="https://biuro.biall-net.pl/wfs/default_db/Types/ant.xsd"/>
       
    <xsl:template match="@Target_file" mode="Types__x3A__ant:tasks_wget_dependencies" xpath-default-namespace="https://biuro.biall-net.pl/wfs/default_db/Types/ant.xsd">
        <dependency><xsl:value-of select="concat(.,'_check')"/></dependency>
        <dependency><xsl:value-of select="concat(.,'_install')"/></dependency>
    </xsl:template>
    <xsl:template match="@Target_file" mode="Types__x3A__ant:tasks_curl_post_wfst_dependencies" xpath-default-namespace="https://biuro.biall-net.pl/wfs/default_db/Types/ant.xsd">
        <dependency><xsl:value-of select="concat(.,'_check')"/></dependency>
        <dependency><xsl:value-of select="concat(.,'_install')"/></dependency>
    </xsl:template>
    <xsl:template match="@xmlfile" mode="Types__x3A__ant:tasks_csv2xml_dependencies" xpath-default-namespace="https://biuro.biall-net.pl/wfs/default_db/Types/ant.xsd">
        <dependency><xsl:value-of select="concat(.,'_csv2xml_check')"/></dependency>
        <dependency><xsl:value-of select="concat(.,'_csv2xml_install')"/></dependency>
    </xsl:template>
    
    
    <xsl:template match="@*" mode="Types__x3A__ant:tasks_dependencies Types__x3A__ant:tasks_wget_dependencies Types__x3A__ant:tasks_csv2xml_dependencies Types__x3A__ant:tasks_curl_post_wfst_dependencies" xpath-default-namespace="https://biuro.biall-net.pl/wfs/default_db/Types/ant.xsd"/>
        
    <xsl:template match="text()" mode="Types__x3A__ant:tasks_dependencies" xpath-default-namespace="https://biuro.biall-net.pl/wfs/default_db/Types/ant.xsd"/>
    <!--<xsl:template match="*">
        <xsl:element name="{name()}">
            <xsl:copy-of select="@*"/>
        </xsl:element>
    </xsl:template>-->
    
</xsl:stylesheet>