se/SE/schema/default_db_xml_cache.public/system_cache__appinfo/postprocess.xsl

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:system_cache__appinfo="http://biuro.biall-net.pl/xmlschema_procesy5/default_db_xml_cache/appinfo.xsd"
    xmlns:system_cache__dita="http://biuro.biall-net.pl/xmlschema_procesy5/default_db_xml_cache/dita.xsd"
    exclude-result-prefixes="xs"
    version="2.0">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>
    
    <!-- used by WPS_Functions/default_db/CRM_PROCES_tree/build_CRM_PROCES_tree.xml target name="default_db:PROCES_INIT:tree:dita"
        and public_html/default_db_xml_cache.public/default_db/tree_to_dita.xsl
    -->
    
    <xsl:param name="temp"  required="yes"/>
    <xsl:param name="uuid" required="yes"/>
    <xsl:param name="postprocess_modules.xml" required="yes"/>
    <xsl:param name="basedir" required="yes"/>
    <xsl:param name="threadcount" select="'10'"/>
    
    <xsl:template mode="system_cache__appinfo:preprocess" match="preprocess_dita">
        <project basedir="{$temp}" name="project_for_{local-name()}" default="default">
            <property name="uuid" value="{$uuid}"/>
            <property name="temp" value="{$temp}"/>
            <target name="default">
                <parallel threadcount="{$threadcount}">
                    <xsl:apply-templates mode="system_cache__appinfo:preprocess"/>
                </parallel>
            </target>
        </project>
    </xsl:template>
    
    <xsl:template mode="system_cache__appinfo:postprocess" match="postprocess_dita">
        <project basedir="{$temp}" name="project_for_{local-name()}" default="default">
            <property name="uuid" value="{$uuid}"/>
            <property name="temp" value="{$temp}"/>
            <target name="default">
                <parallel threadcount="{$threadcount}">
                    <xsl:apply-templates mode="system_cache__appinfo:postprocess"/>
                </parallel>
            </target>
        </project>
    </xsl:template>
    
    
    <xsl:template mode="system_cache__appinfo:postprocess" match="base64_to_image">
        <xsl:choose>
            <xsl:when test="@srcfile and @dstfile">
                <exec executable="base64">
                    <arg line="-i {@srcfile}"/>
                    <arg line="-o {@dstfile}"/>
                    <arg line="-D"/>
                </exec>
            </xsl:when>
            <xsl:otherwise>
                <xsl:message terminate="yes">#29 Not set @srcfile or @dstfile</xsl:message>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    
    <xsl:template mode="system_cache__appinfo:preprocess" match="gml_to_image|graph_to_image">
        <xsl:choose>
            <xsl:when test="@srcfile and @dstfile and @fileindex">
                
                <echo> convert gml 2 png or graph_to_image  for <xsl:value-of select="@srcfile"/> to <xsl:value-of select="@dstfile"/> , @fileindex=<xsl:value-of select="@fileindex"/>; - tymczasowy sposob mapowania do konfigu</echo>
                <xsl:variable name="current_node" select="."/>
                <xsl:variable name="postprocess_modules" select="doc($postprocess_modules.xml)"/>
                <xsl:for-each select="$postprocess_modules/postprocess_modules/node()[name()= current()/name()]">
                    <xsl:for-each select="*">
                        <sequential>
                        <xsl:element name="{name()}">
                            <xsl:copy-of select="@*"/>
                            <property name="basedir" value="{$basedir}"/>
                            <property name="uuid" value="{$uuid}"/>
                            <xsl:for-each select="property">
                                <xsl:element name="{name()}">
                                    <xsl:attribute name="name" select="@name"/>
                                    <xsl:attribute name="value" select="$current_node/@*[name()= current()/@name]"/>
                                    <!--<xsl:copy-of select="@*"/>-->
                                </xsl:element>
                            </xsl:for-each>
                        </xsl:element>
                        </sequential>
                    </xsl:for-each>
                </xsl:for-each>
            </xsl:when>
            <xsl:otherwise>
                <xsl:message terminate="yes">#29 Not set @srcfile or @dstfile</xsl:message>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    
</xsl:stylesheet>