se/SE/schema/WPS_Functions/build_WPS_Functions.xsl

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs"
    version="2.0">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>
    
    <xsl:param name="WPS_Functions" required="yes"/>
    <xsl:include href="../default_db_xml_cache.public/system_cache__appinfo/basedir.xsl"/>
    
    <xsl:template match="WPS_Functions.childproperties.builds">
        <project basedir="{$basedir}" name="WPS_Functions.childproperties.builds" default="WPS_Functions.childproperties.builds">
            <description>
                Generated ant by xsl from childproperties modules, to be run modules in mode to let they give their properties and dependencies
            </description>
            <target name="WPS_Functions.childproperties.builds">
                <xsl:for-each select="tokenize(.,';')">
                    <echo>Running <xsl:value-of select="."/></echo>
                    <xsl:variable name="antfile" select="doc(concat($WPS_Functions,'/',.))"/>
                    <xsl:variable name="default_prefix">
                        <xsl:choose>
                            <xsl:when test="substring-before($antfile/project/@default,':')">
                                <xsl:value-of select="substring-before($antfile/project/@default,':')"/>
                            </xsl:when>
                            <xsl:otherwise/>
                        </xsl:choose>
                    </xsl:variable>
                    <xsl:choose>
                        <xsl:when test="$antfile//target[@name='write_child_props_to_config_dir']">
                            <xsl:message>#23 adding task to read properties for <xsl:value-of select="."/>  - build project default prefix is not used!</xsl:message>
                            <ant antfile="{$WPS_Functions}/{.}" inheritall="yes" inheritrefs="yes" target="write_child_props_to_config_dir"/>
                        </xsl:when>
                        <xsl:when test="$antfile//target[@name=concat($default_prefix,':','write_child_props_to_config_dir')]">
                            <ant antfile="{$WPS_Functions}/{.}" inheritall="yes" inheritrefs="yes" target="{$default_prefix}:write_child_props_to_config_dir"/>
                        </xsl:when>
                        <xsl:otherwise>
                            <xsl:message>#26 WARNING file <xsl:value-of select="."/> doesnt specify task for export properties ( target write_child_props_to_config_dir ) </xsl:message>
                        </xsl:otherwise>
                    </xsl:choose>
                    
                </xsl:for-each>
            </target>
        </project>
    </xsl:template>
    
</xsl:stylesheet>