se/SE/schema/WPS_Functions/get_wfs/get_wfs.Insert.xsl

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:wfs="http://www.opengis.net/wfs"
    xmlns:gml="http://www.opengis.net/gml"
    exclude-result-prefixes="xs"
    version="2.0">
    
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>
    
    <xsl:param name="source.obj" required="yes"/>
    <xsl:param name="target.obj" required="yes"/>
    
    <xsl:param name="READ_ONLY">
        <READ_ONLY>
            <A_RECORD_CREATE_DATE/>
            <A_RECORD_CREATE_AUTHOR/>
            <A_RECORD_UPDATE_DATE/>
            <A_RECORD_UPDATE_AUTHOR/>
        </READ_ONLY>
    </xsl:param>
    
    <xsl:template match="wfs:FeatureCollection">
        <Transaction
            xmlns="http://www.opengis.net/wfs"
            xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
            version="1.0.0"
            service="WFS"
            xmlns:p5_default_db="https://biuro.biall-net.pl/wfs/default_db"
            xmlns:gml="http://www.opengis.net/gml">
           <xsl:apply-templates/>
        </Transaction>
    </xsl:template>
    
    <xsl:template match="gml:featureMember" >
        <Insert xmlns="http://www.opengis.net/wfs">
            <xsl:apply-templates mode="translateSourceToTarget"/>
        </Insert>
    </xsl:template>
    
    
    <xsl:template mode="translateSourceToTarget" match="*[ local-name()= $source.obj]">
        <xsl:namespace name="default_db__x3A__{$target.obj}" select="concat('https://biuro.biall-net.pl/wfs/default_db/',$target.obj)"/>
        <xsl:element name="default_db__x3A__{$target.obj}:{$target.obj}" namespace="https://biuro.biall-net.pl/wfs/default_db/{$target.obj}">
            <xsl:for-each select="*">
                <xsl:choose>
                    <xsl:when test="$READ_ONLY//*[ name() = current()/local-name()]"/>
                    <xsl:otherwise>
                        <xsl:element name="default_db__x3A__{$target.obj}:{local-name()}" namespace="https://biuro.biall-net.pl/wfs/default_db/{$target.obj}"><xsl:value-of select="text()"/></xsl:element>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each>
        </xsl:element>
    </xsl:template>
    
    <xsl:template mode="translateSourceToTarget" match="text()|comment()"/>
    
    <xsl:template mode="translateSourceToTarget" match="*">
        <xsl:message terminate="yes">ERROR found not expected object name=<xsl:value-of select="name()"/> - expected was <xsl:value-of select="$source.obj"/> ;</xsl:message>
    </xsl:template>
    
    
    
</xsl:stylesheet>