se/SE/schema/WPS_Functions/xinclude_p5_recurse/xp5r.apply-templates.xsl

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:xp5r="http://biuro.biall-net.pl/xmlschema_procesy5/default_db_xml_cache.public/xinclude_p5_recurse/xinclude_p5_recurse.xsd"
    exclude-result-prefixes="xs"
    version="2.0">
    
    <xsl:output indent="yes"/>
    
    <xsl:strip-space elements="*"/>
  
    <xsl:param name="xp5r.apply-template.xsl.name" required="yes"/>
    
    <xsl:template match="*" mode="xp5r:apply-templates">
        <project name="{$xp5r.apply-template.xsl.name}" default="default">
            <target name="default">
                <parallel threadcount="10">
                    <xsl:apply-templates mode="xp5r:apply-templates.child"/>
                </parallel>
            </target>
        </project>
    </xsl:template>
    
    <xsl:template match="xp5r:cache" mode="xp5r:apply-templates.child">
        <sequential>
        <condition property="{@xp5r:id}.exists">
            <available file="{@xp5r:basedir}/{@xp5r:id}.xml"/>
        </condition>
            
        <xsl:apply-templates mode="xp5r:apply-templates.child"/>
        </sequential>
    </xsl:template>
    
    
    <xsl:template match="xp5r:apply-template" mode="xp5r:apply-templates.child">
        <xsl:result-document href="{../@xp5r:basedir}/{../@xp5r:id}.xsl">
            <xsl:element name="xsl:stylesheet">
                <xsl:attribute name="version" select="'2.0'"/>
                <xsl:for-each select="../xp5r:namespace">
                    <xsl:namespace name="{@name}" select="@namespace"/>
                </xsl:for-each>
                
                
                
                <xsl:element name="xsl:include">
                    <xsl:attribute name="href" select="../@xp5r:stylesheet"/>
                </xsl:element>
                
                <!--<xsl:element name="xsl:variable">
                    <xsl:attribute name="name" select="'input'"/>
                    <xsl:attribute name="select" select="xp5r:context-node/"/>
                </xsl:element>-->
                <xsl:element name="xsl:template">
                    <xsl:attribute name="match" select="'*'"/>
                    <xsl:choose>
                        <xsl:when test="xp5r:context-node/xp5r:for-each-group">
                            <xsl:element name="xsl:for-each-group">
                                <xsl:attribute name="select" select="xp5r:context-node/xp5r:for-each-group/@select"/>
                                <xsl:attribute name="group-by" select="xp5r:context-node/xp5r:for-each-group/@group-by"/>
                                    <xsl:element name="xsl:apply-templates">
                                        <xsl:attribute name="select" select="@select"/>
                                        <xsl:attribute name="mode" select="@mode"/>
                                    </xsl:element>
                            </xsl:element>
                        </xsl:when>
                        <xsl:otherwise>
                                <xsl:element name="xsl:apply-templates">
                                    <xsl:attribute name="select" select="@select"/>
                                    <xsl:attribute name="mode" select="@mode"/>
                                </xsl:element>
                        </xsl:otherwise>
                    </xsl:choose>
                </xsl:element>
            </xsl:element>
        </xsl:result-document>
        <echoxml file="{../@xp5r:basedir}/{../@xp5r:id}.in.xml"><empty/></echoxml>
        <xslt basedir="{../@xp5r:basedir}" style="{../@xp5r:basedir}/{../@xp5r:id}.xsl"
            in="{../@xp5r:basedir}/{../@xp5r:id}.in.xml" 
            out="{../@xp5r:basedir}/{../@xp5r:id}.xml" 
            force="true"
            >
            <factory name="net.sf.saxon.TransformerFactoryImpl">    
                <attribute name="http://saxon.sf.net/feature/xinclude-aware" value="true"/>
                <!--<attribute name="http://saxon.sf.net/feature/initialMode" value="{@mode}"/>-->
            </factory>
            <xsl:for-each select="../xp5r:param">
                <xsl:element name="param">
                    <xsl:attribute name="name" select="@name"/>
                    <xsl:attribute name="expression" select="@value"/>
                </xsl:element>
            </xsl:for-each>
            <classpath location="/opt/local/share/java/saxon9he.jar"/>
        </xslt>
        <delete file="{../@xp5r:basedir}/{../@xp5r:id}.in.xml"/>
    </xsl:template>
    
    
    <xsl:template match=" text()|comment()" mode="xp5r:apply-templates.child"/>
        
    
    
</xsl:stylesheet>